program mmmmmmmmmmmmm;
{$X+}
uses Crt,Vga13h,RayTrace;

type
  TgaHeader = record { 18 bytes total }
    who_knows: array[1..12] of Byte;
    Width: Word;
    Height: Word;
    BitsPerPixel: Byte;
    who_knows2: Byte;
  end;

const
  DefaultHeader: TgaHeader = (
    who_knows: (0, 0, 2, 0, 0, 0, 0, 0, 0, 0, 0, 0);
    Width: 320;
    Height: 200;
    BitsPerPixel: 24;
    who_knows2: 32
  );

var
  tf: File of Byte;
  tff: File absolute tf;

procedure StartTga(s: String);
begin
  Assign(tf,s);
  Rewrite(tf);
  BlockWrite(tff,DefaultHeader,18);
end;

procedure EndTga;
begin
  Close(tf);
end;

procedure TgaDot(r,g,b: Integer);
begin
  if r > 255 then r := 255;
  if g > 255 then g := 255;
  if b > 255 then b := 255;
  if r < 0 then r := 0;
  if g < 0 then g := 0;
  if b < 0 then b := 0;
  Write(tf,Byte(b),Byte(g),Byte(r));
end;

{ r,g,b:0-255 }
function Rgb(r,g,b: Integer): Integer;
begin
  if r > 255 then r := 255;
  if g > 255 then g := 255;
  if b > 255 then b := 255;
  Rgb := (b shr 6) or ((g shr 3) and $1c) or (r and $e0);
end;

procedure RgbDot(x,y,r,g,b: Integer);
var
  r1,g1,b1,r2,g2,b2,c1,c2: Integer;
begin
  if r > 255 then r := 255;
  if g > 255 then g := 255;
  if b > 255 then b := 255;
  if r < 0 then r := 0;
  if g < 0 then g := 0;
  if b < 0 then b := 0;
  r1 := r and $e0; g1 := g and $e0; b1 := b and $c0;
  r2 := r1 + (r mod 32)+16;
  g2 := g1 + (g mod 32)+16;
  b2 := b1 + (b mod 64)+32;
  c1 := Rgb(r1,g1,b1); c2 := Rgb(r2,g2,b2);
  if (x mod 2) = (y mod 2) then PutPixel(x,y,c1) else PutPixel(x,y,c2);
end;

procedure SetUpRgb;
var
  Clrs: array[0..255,0..2] of Byte;
  i: Integer;
begin
  for i := 0 to 255 do begin
    Clrs[i,0] := (i and $e0) shr 2;
    Clrs[i,1] := (i and $1c) shl 1;
    Clrs[i,2] := (i and 3) shl 4;
    case Clrs[i,2] of
      15..31: Inc(Clrs[i,2],4);
      32..63: Inc(Clrs[i,2],8);
    end;
  end;
  SetColorBlock(0,256,Clrs);
end;

procedure Save(var u: Universe; st: String);
var
  x,y: Integer;
  c: LongInt;
  r,g,b: Integer;
begin
  StartTga(st);
  x := 0;
  for y := 0 to u.Height-1 do
    for x := 0 to u.Width-1 do begin
      c := u.TracePoint(x,y);
      r := (c and $ff0000) shr 16;
      g := (c and $ff00) shr 8;
      b := c and $ff;
      RgbDot(x,u.Height-1-y,r,g,b);
      TgaDot(r,g,b);
    end;
  EndTga;
end;

procedure Draw(var u: Universe);
var
  x,y: Integer;
  c: LongInt;
begin
  x := 0;
  while (x < u.Width) and (not KeyPressed) do begin
    for y := 0 to u.Height-1 do begin
      c := u.TracePoint(x,u.Height-1-y);
      if c <> 0 then
        RgbDot(x,y,(c and $ff0000) shr 16,(c and $ff00) shr 8,c and $ff);
    end;
    Inc(x);
  end;
end;

procedure Qwik(var u: Universe);
var
  x,y: Integer;
  c: LongInt;
  r,g,b: Byte;
begin
  x := 0;
  while (x < (u.Width div 2)) and (not KeyPressed) do begin
    for y := 0 to (u.Height div 2)-1 do begin
      c := u.TracePoint(x*2,u.Height-1-(y*2));
      if c <> 0 then begin
        r := (c and $ff0000) shr 16;
        g := (c and $ff00) shr 8;
        b := c and $ff;
        RgbDot(x*2,y*2,r,g,b); RgbDot(x*2+1,y*2,r,g,b);
        RgbDot(x*2+1,y*2+1,r,g,b); RgbDot(x*2,y*2+1,r,g,b);
      end;
    end;
    Inc(x);
  end;
end;

procedure Zoom(var u: Universe);
var
  x,y,i,j: Integer;
  c: LongInt;
  r,g,b: Byte;
begin
  x := 0;
  while (x < (u.Width div 4)) and (not KeyPressed) do begin
    for y := 0 to (u.Height div 4)-1 do begin
      c := u.TracePoint(x*4,u.Height-1-(y*4));
      if c <> 0 then begin
        r := (c and $ff0000) shr 16;
        g := (c and $ff00) shr 8;
        b := c and $ff;
        for i := 0 to 3 do
          for j := 0 to 3 do
            RgbDot(x*4+i,y*4+j,r,g,b);
      end;
    end;
    Inc(x);
  end;
end;

procedure Beep;
begin
  Sound(220);        { Beep }
  Delay(200);        { For 200 ms }
  NoSound;           { Relief! }
end;

type
  pplane = object(Plane)
    function GetColor(aray: Ray; time: Real): LongInt; virtual;
  end;
  ColorSphere = object(Sphere)
    rc,gc,bc: Byte;
    constructor Init(x,y,z,r: Real; cr,cg,cb: Byte);
    function GetColor(aray: Ray; time: Real): LongInt; virtual;
  end;
  WeirdSphere = object(Sphere)
    function GetColor(aray: Ray; time: Real): LongInt; virtual;
  end;

constructor ColorSphere.Init(x,y,z,r: Real; cr,cg,cb: Byte);
begin
  Sphere.Init(x,y,z,r);
  rc := cr; gc := cg; bc := cb;
end;

function ColorSphere.GetColor(aray: Ray; time: Real): LongInt;
var
  r: Ray;
  c: LongInt;
  cc: record b,g,r: Byte end absolute c;
begin
  ReflectRay(aray,time,r);
  c := Owner^.TraceRay(r);
  cc.r := Integer(cc.r) div 2 + rc;
  cc.g := Integer(cc.g) div 2 + gc;
  cc.b := Integer(cc.b) div 2 + bc;
  GetColor := c;
end;

function WeirdSphere.GetColor(aray: Ray; time: Real): LongInt;
var
  r: Ray;
begin
  r.ox := (aray.dx * time + aray.ox - xp - ra) / (ra*2);
  r.oy := (aray.dy * time + aray.oy - yp - ra) / (ra*2);
  r.oz := (aray.dz * time + aray.oz - zp - ra) / (ra*2);
  (*GetColor := GetHsv(Round(r.oy*359),Round(r.ox*100),100{Round(r.oz*100)});*)
  GetColor := GetHsv(Round(r.oy*359),100,100);
end;

function pplane.GetColor(aray: Ray; time: Real): LongInt;
var
  r: Ray;
  c: LongInt;
  cc: record b,g,r: Byte end absolute c;
begin
  ReflectRay(aray,time,r);
  c := Owner^.TraceRay(r);
  cc.r := Integer(cc.r) div 2 + 128;
  cc.g := Integer(cc.g) div 2 + 128;
  cc.b := Integer(cc.b) div 2;
  GetColor := c;
end;

procedure TraceIt;
var
  u: Universe;
  p: ColorSphere;
  r,g,b,w: ColorSphere;
  ws: WeirdSphere;
  ss: array[0..17] of ColorSphere;
  i,j,k,l,m: Integer;
begin
  u.Init(320,200);
  p.Init(100,-1004,0, 1000, 128,128,0);
  r.Init(-15,-3,50,5, 128,0,0);
  g.Init(-10,-3,41,5, 0,128,0);
  b.Init(-5,-3,50,5, 0,0,128);
  w.Init(-10,4,47,5, 128,128,128);
  ws.Init(15,6,100, 15);
  for i := 0 to 17 do begin
    Hsv2Rgb(i*20,100,100,j,k,l);
    ss[i].Init(15+(sin(i*pi/9)*20),6,100+(cos(i*pi/9)*20),2, j div 2,k div 2,l div 2);
  end;
  u.Insert(@ws);
  u.Insert(@p);
  u.Insert(@r);
  u.Insert(@g);
  u.Insert(@b);
  u.Insert(@w);
  for i := 0 to 17 do
    u.Insert(@ss[i]);
  Save(u,'brooke4.tga');
  {Zoom(u);}
  Beep;
  u.Done;
end;

begin
  Set13h;
  SetUpRgb;
  TraceIt;
  ReadKey;
  BiosMode(3);
end.