dither4/dither4.s

SAVMSC = $58
COLPF0 = $D016
COLPF1 = $D017
COLPF2 = $D018
COLPF3 = $D019
COLBK = $D01A

AUDC1 = $D201
DMACTL = $D400
DLISTL = $D402
DLISTH = $D403
WSYNC = $D40A
VCOUNT = $D40B
NMIEN = $D40E

temp1l = $80
temp1h = $81
temp1 = temp1l
temp2l = $82
temp2h = $83
temp2 = temp2l
sample_ptrl = $84
sample_ptrh = $85
sample_ptr = sample_ptrl
scanline = $86
audiotemp = $87

height = 160
bytes_per_line = 40
pages_per_frame = 32
lines_per_frame = 262
;scanline_offset = 31 + (40 - 24) / 2
scanline_offset = 47
scanline_max = (lines_per_frame - scanline_offset) / 2

.data

.import audio_samples
.import audio_samples_end

.import frame1_top
.import frame1_bottom
.import frame1_palette1
.import frame1_palette2
.import frame1_palette3
.import frame2_top
.import frame2_bottom
.import frame2_palette1
.import frame2_palette2
.import frame2_palette3

displaylist:
    ; 40 lines overscan
    .repeat 5
        .byte $70 ; 8 blank lines
    .endrep

    ; 160 lines graphics
    ; ANTIC mode e (160px 2bpp, 1 scan line per line)
    .byte $4e
    .addr frame1_top
    .repeat height / 2 - 1
        .byte $0e
    .endrep
    .byte $4e
    .addr frame1_bottom
    .repeat height / 2 - 1
        .byte $0e
    .endrep

    .byte $41 ; jump and blank
    .addr displaylist

;fixme use
displaylist_part2:
    ; 40 lines overscan
    .repeat 5
        .byte $70 ; 8 blank lines
    .endrep

    ; 160 lines graphics
    ; ANTIC mode e (160px 2bpp, 1 scan line per line)
    .byte $4e
    .addr frame2_top
    .repeat height / 2 - 1
        .byte $0e
    .endrep
    .byte $4e
    .addr frame2_bottom
    .repeat height / 2 - 1
        .byte $0e
    .endrep

    .byte $41 ; jump and blank
    .addr displaylist


audio_high_byte:
    .scope
        .macro byteseq val
            .repeat 16
                .byte val | $10
            .endrep
        .endmacro
        byteseq $0
        byteseq $1
        byteseq $2
        byteseq $3
        byteseq $4
        byteseq $5
        byteseq $7
        byteseq $8
        byteseq $9
        byteseq $a
        byteseq $b
        byteseq $c
        byteseq $d
        byteseq $e
        byteseq $f
    .endscope

.code

.export start

.proc start
    ; Set up the audio sample buffer
    lda #.lobyte(audio_samples)
    sta sample_ptrl
    lda #.hibyte(audio_samples)
    sta sample_ptrh

    ; Disable display DMA
    lda #$00
    sta DMACTL

    ; Disable VBI and DLI but allow Reset
    lda #$20
    sta NMIEN

    ; Set up the display list
    lda #.lobyte(displaylist)
    sta DLISTL
    lda #.hibyte(displaylist)
    sta DLISTH

    ; Manually wait for first scan line
wait_vblank:
    sta WSYNC
    lda VCOUNT
    bne wait_vblank

    ; Re-enable display DMA
    lda #$22
    sta DMACTL

wait_start:
    ; Wait for the vblank
    ; Resynchronize the scanline counter
wait_loop:
    lda VCOUNT
    tay ; save for audio lookup
    bne wait_loop
    lda #(256 - scanline_offset)
    sta scanline

each_scanline:
    .macro audio_prep
        ; Y is VCOUNT at entry
        lda (sample_ptr),y ; 5/6 cyc
        sta audiotemp ; 3 cyc
    .endmacro

    .macro inner_scanline frame_base
        ; it'll fire on unused lines, but harmlessly
        ldy scanline ; 3 cyc
        inc scanline ; 5 cyc

        ; Leisurely memory fetches
        lda frame1_palette1,y ; 5 @FIXME alternate
        pha                   ; ...3?
        ldx frame1_palette2,y ; 5
        lda frame1_palette3,y ; 5
        tay
        pla

        ; Wait for horizontal blank
        sta WSYNC

        ; Update color registers as fast as possible
        sta COLPF0
        stx COLPF1
        sty COLPF2
    .endmacro

    .macro audio_play_lo ; 11 cycles
        lda audiotemp ; 3 cyc
        and #$0f ; 2 cyc
        ora #$10 ; 2 cyc
        sta AUDC1 ; 4 cyc
    .endmacro

    .macro audio_play_hi ; 12 cycles
        ldy audiotemp ; 3 cyc
        lda audio_high_byte,y ; 5 cyc
        sta AUDC1 ; 4 cyc
    .endmacro

    .macro audio_inc
        ; Increment sample ptr
        clc
        lda sample_ptrl
        adc #130
        sta sample_ptrl
        lda sample_ptrh
        adc #0
        sta sample_ptrh

        cmp #.hibyte(audio_samples_end)
        bne audio_cont

        ;lda sample_ptrl
        ;cmp #.lobyte(audio_samples_end)
        ;bne audio_cont

        lda #.lobyte(audio_samples)
        sta sample_ptrl
        lda #.hibyte(audio_samples)
        sta sample_ptrh

        audio_cont:
    .endmacro

    ;audio_prep
    inner_scanline
    ;audio_play_lo
    inner_scanline
    ;audio_play_hi

    lda VCOUNT
    tay ; save for audio lookup
    cmp #130 ;#130
    bne each_scanline
    audio_inc
    jmp wait_start

.endproc

; temp1 contains source address
; temp2 contains dest address
; clobbers a/x/y
; incremepts temp1 and temp2 to the end of their regions
.proc copy_half_frame
    ldx #0

copy_loop_lines:
    ldy #00

copy_loop_bytes:
    lda (temp1),y
    sta (temp2),y
    iny
    cpy #bytes_per_line
    bne copy_loop_bytes

    clc
    lda temp1l
    adc #bytes_per_line
    sta temp1l
    lda temp1h
    adc #00
    sta temp1h

    clc
    lda temp2l
    adc #bytes_per_line
    sta temp2l
    lda temp2h
    adc #00
    sta temp2h

    inx
    cpx #(height / 2)
    bne copy_loop_lines

    rts
.endproc